Popis problému:

Tento záznam popisuje, jak pomocí rozhraní CDO odeslat z obecné aplikace fax a nastavit mu všechny potřebné parametry, včetně schedulingu, krycí strany atd.

Řešení problému:

Spolu s MS Outlookem je možno nainstalovat COM objekt CDO (Collaboration Data Objects), který umožňuje z obecné aplikace (a obecného programovacího jazyka) odeslat e-mail -- a i fax. Nastavení specifických vlastností zprávy pro FaxChange však není na první pohled zřejmé.

Zde je útržek kódu ve Visual Basic skriptu, který odešle fax a nastaví mu všechny parametry pro FaxChange, které nastavit jdou. Stejným způsobem je CDO možno použít i v jiných programövacích jazycích.

Dim ProfileName
' Select your MAPI profile
ProfileName = "Petr Brouzda"
Dim objSession
Dim objMessage
Dim objOneRecip
' Create a session
Set objSession = CreateObject("MAPI.Session")
' Change the parameters to valid values for your configuration
objSession.Logon ProfileName
' Create a message and fill in its properties
Set objMessage = objSession.Outbox.Messages.Add
objMessage.Subject = "Sample Message"
objMessage.Text = "This is sample message text."
' Create the recipient
Set objOneRecip = objMessage.Recipients.Add
objOneRecip.Name = "Datasys Support Line[fax:+420261388444]"
objOneRecip.Type = 1
objOneRecip.Resolve
' -----------------------------------------------------------------
' FaxChange custom properties:
' Coversheet
' 0 = default coversheet
' 1 = no coversheet
' 3 = specific coversheet, property &h510f001e should be filled with coversheet name
objMessage.Fields.Add &h510B0003, 3
objMessage.Fields.Add &h510f001e, "bigsample.cvs"    'only to be enabled if "specific coversheet" should be used
' Scheduling... is not easy
' 51010003 : 0 = send now
'            1 = schedule
'
' Following fields are used only when 51010003 = 1:
' 51030003 = day offset : 0 = today
'                         1 = tomorrow
'                         2 = monday, 3 = tuesday ...
' 51060003 = hour (0-23)
' 51090003 = quarter-hour ( 0 = 00 min, 1 = 15 min, 2 = 30 min, 3 = 45 min )
'
' This sample schedules the fax to Wednesday, 22:45
objMessage.Fields.Add &h51010003, 1
objMessage.Fields.Add &h51030003, 4
objMessage.Fields.Add &h51060003, 22
objMessage.Fields.Add &h51090003, 3
' Preview
' 1 = send preview
' 2 = don't sent preview
objMessage.Fields.Add &h516B0003, 2
' Resolution
' If set, resolution of 100 DPI (low) will be used. Otherwise 200 DPI (fine) is used.
' objMessage.Fields.Add &h51670003, 1
' Custom items 1 to 3
objMessage.Fields.Add &h5160001e, "Custom field 1"
objMessage.Fields.Add &h5161001e, "Custom field 2"
objMessage.Fields.Add &h5162001e, "Custom field 3"
' User ID
objMessage.Fields.Add &h5170001e, "My specific ID 723472374"
' Custom CSID
objMessage.Fields.Add &h5173001e, "DATASYS CSID"
' Costcode
' 0 = use default costcode
' 1 = use specific costcode
objMessage.Fields.Add &h51200003, 1
objMessage.Fields.Add &h5122001e, "MyCostCode1"
' -----------------------------------------------------------------
' Send the message and log off
objMessage.Send True, False
' All OK, logoff
objSession.Logoff

Další informace:

• Tento způsob odesílání funguje jen tehdy, pokud je FaxChange nainstalovaná s MS Exchange gatewayí.
• CDO objekt je standardní součástí instalace MS Outlook 98. V MS Outlook 2000 není ve standardní instalaci - je potřeba zvolit "custom" instalaci a označit CDO k nainstalování.
• K odesílání se používá standardní MAPI profil -- ten tedy musí být nakonfigurován.
• Náhled, potvrzení o (ne)odeslání a ostatní zprávy dorazí do mailboxu určeného v MAPI profilu.

Klíčová slova:

FaxChange,API,CDO,odeslat,odeslat fax,programově

V případě nejasností napište prosím na adresu development@datasys.cz.